You can use the new LAMBDA function in Excel (Desktop edition) to create custom, reusable functions and call them by a friendly name. The custom function is available throughout the workbook and can be called like native Excel functions.
The Excel Labs (formerly Advanced Formula Environment) add-in’s Import from Grid feature can be used to create the LAMBDA function from an example you create.
For the purpose of this article, I wanted to create a LAMBDA function to calculate the financial ratio (Receivables Turnover ratio for this example) from the Trial Balance table exported from Quickbooks Online. However, any Trial Balance table can be used as long as it follows the format used for this table. The following screenshot shows the part of the table used in this example.
The function takes the Financial Year as a parameter and calculates the Receivable Turnover ratio as follows:
Receivable Turnover = Revenue / Average of Beginning and Ending Accounts Receivable
I started by building my example (B2:E2) using the SUMIFS function as shown in the screenshot below.
I then used the Excel Labs add-in’s Import from Grid feature to build the LAMBDA function.
However, the add-in produced the following error because the Table reference cannot be used in the LAMBDA function.
A workaround for this limitation is to use the INDIRECT function to reference the required tables and columns in the LAMBDA formula. I changed the formulas as shown in the screenshot below.
=SUMIFS(
INDIRECT("TrialBalance[Balance]"),
INDIRECT("TrialBalance[Financial Year]"),A2,
INDIRECT("TrialBalance[Account Type]"),"Accounts Receivable (A/R)"
)
Clicking the Preview button generated the following code with a warning:
The warning is related to the INDIRECT function. The INDIRECT function is volatile because the range of the table is unknown and can change. As such it may cause the entire workbook to be recalculated frequently. Volatile functions can impact performance, especially for large workbooks. You can set the "Manual" calculation option to avoid automatic recalculation.
Here is the complete LAMBDA function generated by the add-in:
RecvTO = LAMBDA(FinYear,
LET(
EndAR, SUMIFS(
INDIRECT(
"TrialBalance[Balance]"
),
INDIRECT(
"TrialBalance[Financial Year]"
), FinYear,
INDIRECT(
"TrialBalance[Account Type]"
), "Accounts Receivable (A/R)"
),
BegAR, SUMIFS(
INDIRECT(
"TrialBalance[Balance]"
),
INDIRECT(
"TrialBalance[Financial Year]"
), FinYear - 1,
INDIRECT(
"TrialBalance[Account Type]"
), "Accounts Receivable (A/R)"
),
Revenue, SUMIFS(
INDIRECT(
"TrialBalance[Balance]"
),
INDIRECT(
"TrialBalance[Financial Year]"
), FinYear,
INDIRECT(
"TrialBalance[Account Type]"
), "Income"
) * -1,
Revenue /
((EndAR + BegAR) / 2)
)
);
You can verify your custom function by entering it in any cell. See the F2 cell below containing the custom function: =RecvTO(A2).
You can download the above Excel workbook here. Note that you will need to install the Excel Labs add-in to use the Import from Grid feature.
